"Adrift" by Ian C Dunbar

Include Basic Screen Effects by Emily Short.

Release along with the source text, a website, and an interpreter.
Use serial comma.

Chapter 1 - Rooms

	Spawning Chamber is a room.
	The description of Spawning Chamber is "Cold, Light, Slimey. You open your eyes, you are disoriented and confused. Looking down you see a paneled, metallic floor covered in goo from the hibernation chamber. Hibernation chamber. 'Why did I have that thought?' The floor is vibrating slightly, you begin to notice a hum that is permiating around the room. Engines. 'Why engines? Why am I awake? I shouldn't be awake.' There should be an attendant helping you out of your pod, waking up from hypersleep is an arduous task even with help. Something is wrong. Other than a persistant hum, the ship is ghostly quiet, not the bustling place it was before you entered hypersleep. 'Have I woken up prematurely?' Should you ever lose your way or become overwhelmed, just take a moment and THINK.[ln 2]You feel something odd on your wrist."
	
Section - Fluff
	
	Observation Deck is a room. "A huge dome expands up like a bubble in space provding a wide angle view out into the darkness, it is almost diorienting. The floor barren except for a few benches and chairs."
	
	Labs is a room. "Clean and sterile, bright white lights flood the room as soon as you arrive. Unlike other parts of the ship, the lab is bustling with activity. Robots performing minor experiments and developing new technologies. A memory surfaces, Downtime science."
	
	Bridge is a room. "A commanding view unfolds before you as you step out of the transit landing zone. Several concentric circles of various computer terminals and navigation stations surround a shallow mound. A spire juts up through the mound as if it had been peirced. [if running of server is true]The spire is alive with electronic activity, vigourously tending to thousands of minute tasks.[else]A small pattern of lights on the spire flash periodically.[end if] Three hypersleep vessels ring the base of the spire. These must be the command vessels. [if Stasis is visited]Much more opulent than the crew's pods, these vessels have been designed with care to ensure the safety of their passengers. Thankfully these have been untouched by the rot that has aflicted the general crew.[end if]".
	
Section - Puzzle
	
	Server Room is a room. "Collossal banks of servers rise up to the ceiling like pillars.[if running of server is false] It is cold and quiet in here. That seems strange to you, memories begin to surface, this room should be very warm.[else] Now that the servers are running again its starting to become uncomfortably hot in here.[end if][ln 1]The metallic floor is heavily polished, you can clearly see your reflection standing beneath you. Rising out of the floor in front of three towers is a terminal. Large wires conect the three towers to one another, each hums contently with what must be thousands of volts."
	
	Stasis Chambers is a room. "Your knees buckle under you, the gravity is significantly stronger here. After regaining your composure, you look around. You're in the middle of a long hallway, with pods lining each side. Curiously, you notice that the horizon bends upwards. It appears to be uphill both ways.'This is where I should be... Why did I not wake up in here?' Here the passengers slumber peacefully in hypersleep, allowing the years of space travel to pass by instantly. A status screen is located near you above the pods and just beneath it there is a loose floor panel. A maintinence opening leads down to the subfloor.[ln 2] [if flowing of valves is false]You smell it before you notice it, a rancorous stench wafts past you. Turning around you see that many of the pods have an ominous green tint.[else]The odor is receeding as the nano-biotics return to work, salvaging what they can and digesting the rest. A peacful way to go, utterly painless. Yet greusome none the less.[end if]".
	
	Down from stasis is Life Support Subfloor. Description of life support is "The gravity is even stronger down here, and is becoming uncomfortable. Its like you've never used your legs before. You are surrounded by various pipes and machines, whos functionality escape you, but one thing catches your attention. A factory cell for the nano-biotic. Back up through the maintenence hatch is the stasis chambers."
	
	Engine Room is a room. "You stand of a balcony looking down into the belly of the ship. Two pillars extend downwards, glowing faintly. These are the engines, the voice in the back of you head wispers. Marvels of mankind, capable of hurling humans far into the reaches of space."

Chapter 2 - Things

Section - General
	
	Playspace is a list of rooms variable. playspace is {Server Room, Stasis Chambers, Engine Room, Observation Deck, Labs, Bridge}.
	Fluff rooms is a list of rooms variable. Fluff rooms is {Observation Deck, Labs}.
	Puzzle rooms is a list of rooms variable. Puzzle Rooms is {Server Room, Stasis Chambers, Engine Room}.
	
	Revelation is a truth state variable. revelation is false.
	
	The player is holding a thing called Fast Transit Unit. The description of Fast Transit Unit is "[if FastTransitMem is listed in mems of player][recall][else]The source of the irritation is a curious little device growing out of your skin. It is as much a part of you as your hands or feet. A hard plastic screen covers most of the device. You run your finger over the device, instantly it springs to life sending a warm hum up through your arm.[end if]".

Section - Bridge

	Spire, command vessels, lights, terminals, mound, transit landing zone are scenery in Bridge.
	
	The description of spire is "[recall]Towering above you, the spire nearly scrapes the ceiling with its pinnacle. [if running of server is false]The monolithic structure appears to be a computer of some kind, though it appears to be in a stand by mode.[else]Up close the behemoth radiates heat as the computer preforms its duties, clearly an extension of the server system. You wonder if the cavernous halls of the server room lie just beneath your feet.[end if]."
	
	The description of command vessels is "[recall]Standing equidistant from one another, the command vessels form a triangle around the spire.[command desc]"

Section - Objectives

	Objective is a kind of thing. 
	An objective has a objective called preobj. Preobj is usually NullObj.
	An objective has a objective called target. Target is usually NullObj.
	An objective has a truth state called current. current is usually false.
	An objective has text called goals.

	NullObj is an objective.
	
	MainObj is an objective. current of MainObj is true. target of MainObj is Main2Obj.
	Goals of mainObj is "You have woken up alone and confused aboard a space ship, you have no idea who you are except from what you can glean from fleeting memories. Search the ship looking for clues as to who you are."
	
	Main2Obj is an objective. preobj of Main2Obj is mainObj. Target of Main2Obj is main3Obj.
	Goals of main2Obj is "You take comfort in the fact that you have fix all of the problems aboard the ship, it sure was fortunate that you woke when you did. However you still arent quite sure why you're awake. Hopefully examining other parts of the ship will reveal clues or memories."
	
	Main3Obj is an objective. preobj of Main3Obj is main2Obj.
	Goals of Main3Obj is "The picture is slowly becoming clear as your memories return to you, but you still feel something is nagging at the back of your head. You feel drawn towards the bridge, perhaps more answers lie there."
	
	Rorge1Obj is an objective.
	
	Comm1Obj is an objective.
	
	Serv1Obj is an objective. target of Serv1Obj is Serv2Obj. Current of serv1Obj is true.
	Goals of Serv1Obj is "The servers appear to have been shut down. You know that they need to be restarted for the ship to function correctly but you can't remember how..."
	
	Serv2Obj is an objective. target of Serv2Obj is Serv3Obj. Preobj of Serv2Obj is serv1Obj.
	Goals of Serv2Obj is "You now remember how to activate the servers, though it still may be easier said than done."

	Serv3Obj is an objective. preobj of serv3Obj is serv2Obj.
	Goals of Serv3Obj is "You have successfully restarted the servers, leading you one step closer to discovering the secrets this ship yet conceals."
	
	Stas1Obj is an objective. Target of Stas1Obj is stas2Obj.
	Goals of Stas1Obj is "Many of the hypersleep pods containing the passengers have begun to rot, you need to figure out what is causing the infection and stop it before thousands more die."

	Stas2Obj is an objective. Target of Stas2Obj is Stas3Obj. Preobj of stas2Obj is Stas1Obj.
	Goals of Stas2Obj is "It appears that the flow of Nano-Biotic has stopped after a safety valve deteced abnormally high pressure, allowing infection to spread throughout the hypersleep pods."
	
	Stas3Obj is an objective.Target of Stas3Obj is Stas4Obj. Preobj of stas3Obj is stas2Obj.
	Goals of stas3Obj is "The pressure has now been lowered, it should now be safe to open the Nano-Biotic valve."
	
	Stas4Obj is an objective. Preobj of stas4Obj is stas3Obj.
	Goals of stas4Obj is "With the Nano-Biotic circulating once again around the pods this mess can finally be cleaned up, though some have died many more shall continue to sleep peacefully."

Section - Memories
	
	A memory is a kind of thing. A memory has text called thoughts.  thoughts is usually "".
	A memory has a list of things called targets. A memory has text called collection. Collection is usually "".
	A memory has a memory called prereq. Prereq is usually NullMem.
	
	NullMem is a memory. 
	
	FastTransitMem is a memory. The mem of fast transit unit is {FastTransitMem}. The targets of fastTransitMem is {Fast Transit Unit}.
	Thoughts of FastTransitMem is "'The Fast Transit Unit' bubbles up a voice from your subconscious. A marvel of mordern technology, it allows for instantanious travel between preprogrammed destinations. Of course you dont know if this is true, but it sounds right. The screen of the device glows faintly, displaying:[line break][available rooms][line break][line break]You recall that all you need to do to operate this device is to GO TO an available location."
	
	ServerMem is a memory. The mem of terminal is {ServerMem}. The targets of ServerMem is {Terminal}.
	Thoughts of ServerMem is "[italic type]Rain lashes agains the window. [ln 2]'Shut it down, and reset the breakers, you did it wrong again. If this was the real deal you would be dust right now.' I say. [ln 2]It's really not that complicated, a five year old could do it. I'll be glad when we are done training these new techs. [ln 2]'Try to get this through your head, when transferring power, the highest level of power is always transferred first. Additionally you cannot transfer power of a lower level to a tower with a higher level of power, so if the right tower has the top node powered, you cannot power the middle node, you must first transfer the top node to another tower. Once you activate all of the nodes on the right tower the server system will come back online.' [ln 2]It has been a very long day and the rain pounds ever on.[ln 2][roman type]".

	ShockMem is a memory. The mem of wires is {ShockMem}. The targets of ShockMem is {Left Tower, Middle Tower, Right Tower}.
	Thoughts of ShockMem is "[italic type]Well at least the techs are expendable, unlike me, they arent exactly the most skilled of laborers.  And to be honest, I took slight pleasure in the sight of one of the more annoying techs go up in smoke while attempting to turn on the server, sick as though it may be. He should have paid more attention during training...[roman type]".
	
	BadgeMem is a memory. The mem of badge is {BadgeMem}. The targets of BadgeMem is {command vessels}.
	Collection of badgeMem is "[italic type][ln 1]Rorge Anderson, my only friend and biggest rival. Ever since primary school we have been competing in intellectual events. We were always trying to one up each other.[ln 1][roman type]".
	Thoughts of BadgeMem is "'[italic type]Ill see you on the other side, its all in your hands now' chuckled Rorge.[ln 2]I look at him and nod, he had the easy part. Runtime science is trivial compared to Downtime. The lid on Rorge's hypersleep pod hisses shut. Only a few of us are still awake, more preperations have to be made before Downtime can begin. Humans have never been in hypersleep for as long as we will, everything must be perfect.[ln 1][roman type]".
	
	GuageMem is a memory. The mem of status screen is {GuageMem}. The targets of guageMem is {valves}.
	Collection of GuageMem is "[italic type][ln 1]Nano-biotics. My talents really do go under appreciated. An artificial army of nano bots with the express intent of maintaining sanitation within the hypersleep pods. Without this marvel, humans would be able to survive hypersleep no longer than a couple of years.[ln 1][roman type]".
	Thoughts of GuageMem is "[italic type][ln 1]'What is the point of the safety valve? When would we ever need to shut the nano-biotic down?' asked a tech.[ln 2]'Don't worry its just a precaution, like a surge protector it limits the amount of nano-biotic in the system It will trigger if the pressure is too high and will reset once the system has re-normalized.' I dont expect this will ever be used, but its best to err on the side of caution. The valve can be manually overriden but that could be dangerous if the pressures havent normalized yet.[ln 1][roman type]".
	
	RoboMem is a memory. The mem of Robots is {RoboMem}. The targets of roboMem is {Experiments}.
	Collection of RoboMem is "[italic type][ln 1]If only I had more of these robots instead of the incompitent techs. Its unfortunate that we have already gone over budget on the Tabernacle Project. At least in Downtime there wont be any of these techs around to screw things up. If you want something done, either do it yourself or build a robot.[roman type][ln 1]".
	Thoughts of RoboMem is "[italic type][ln 1]'Ladies and Gentlemen of the Emergency Dictoral Navy's board of Tablernacle oversight, I have come before you today to demonstrate my solution for Downtime. I present DEUS, the Downtime Experiment and Utility System. DEUS is a simulated intelligence and will be in charge of regulating many of the primary functions of the Tabernacle during Downtime, primarily dealing with experimentation and technological evolution.[roman type][ln 1]".
	
	CommMem is a memory. The mem of engines is {CommMem}. The targets of CommMem is {command vessels}.
	Collection of CommMem is "[italic type][ln 1]'Beautiful aren't they?'[ln 2]The voice startles me, jarring my attention away from the installation of Engine 01. I ignore most everybody on this project, but it's not every day that the Commander pays you a visit.[ln 2]'Well it isn't just the superficial structure I find alluring' I reply 'There is a mathematical beauty present as well, a quantitative allure overshadowed only by the power of their purpose.'[ln 2] She smiles at me.[ln 1][roman type]".
	Thoughts of CommMem is "[italic type][ln 1]A navigator calls out to the commander [ln 2]'We have left the solar system ma'am' [ln 2]'Very good, alert the crew that we will begin Downtime preperations shortly.'[ln 2]A hush falls over the bridge. This is it, my time to shine. In short order the fruit of my life's labor will come to bear. The bridge crew return to their duties, they knew it was coming, though they are nervous now that Downtime is upon them. I'll admit, I am nervous too, so much depends on me now.[ln 2][roman type]".
	
	ServerWinMem is a memory.
	
	StasisWinMem is a memory.
	
Section - Modifications
	
	The player has a number called Version. The version of player is 1.
	The player has a number called MemCount. The memCount of player is 0.
	The player has a list of memory called Mems.
	The player has a list of objective called objs.
	Thing has a list of memory called mem. mem is usually {}.
	
Section - Engine Room	

	Engines are scenery in engine room. The description of engines is "You can feel the thrum of the engines deep within your chest. Two glowing beacons in what would otherwise be dark and empty space. The engines breathe life into every corner of the ship."
	
Section - Labs

	Robots is scenery in Labs. The description of robots is "Countless robots of all shapes and sizes are all hard at work, each one specially tailored to the task they are undertaking."
	Experiments is scenery in Labs. The description of experiments is "[recall]".
	
	A badge is a thing in labs. The description of the badge is "Rorge Anderson, Lead Runtime Scientist[ln 1]E.D.N Tabernacle".
		
Section - Server Room

	The server room has a truth state called running. running of server is false.
	
	Reflection is scenery in server room.
	A Hanoi is a kind of thing. It is fixed in place. Hanoi has a truth states called Level1, Level2, Level3.  Level1, Level2, Level3 are usually false.
	The description of a Hanoi is "Like the other two, the [noun] is a tall metallic structure, tough it is drawfed by the monolithic server racks behind it. Three power nodes rise up the column, with the top just barely within arms reach. [ln 2][recall][if level1 of noun is true or level2 of noun is true or level3 of noun is true]The tower hums slightly due to the power running through it.[end if]".
	
	Left Tower, Middle Tower, Right Tower are Hanois in Server Room.
	Level1 of Left Tower is true. Level2 of Left Tower is true. Level3 of Left Tower is true.
	A terminal is scenery in the server room. "[recall][if running of server is false]The current status of the servers is: off. To begin boot sequence activate the right tower by TRANSFER (source tower) TO (destination tower).[else]The current status of the servers is: on.[end if]".
	Wires are scenery in the server room.

Section - Stasis Chambers

	The Stasis Chambers has a truth state called fixed. fixed of stasis is false.

	Pods is scenery in Stasis Chambers. The description of pods is "[recall][ln 2]Thousands of pods extend in either direction before finally curving out of sight. Nametags and IDs adorn each station, embossed on a little serial card. A name on a nearby pod catches your eye. Quintin MacMillan. The inside of the pod next to MacMillan's is covered in the green slime,[if flowing of valves is false] some beginning to seep through the edges of the pod.[else] though now it is slowly receeding.[end if]".
	
	The loose floor panel is a closed opaque openable scenery container in stasis chambers. The description of loose floor panel is "[if loose floor panel is open]The open panel has revealed a set of valves. [else]One of the panels on the floor is askew, it looks as if you could slide your fingers around it to open it.[end if]".
	The status screen is scenery in stasis chambers. status has a truth state called low pressure. low pressure is false.
	The description of status is "A large panel connected to cables leading into the subfloor. Two pressure guages sit on the panel, one reads Nutrients and the other Nano-Biotic.[if low pressure of status is true] Both guages are reading normal levels.[else] While the nutrient pressure looks normal, the nano-biotic pressure is deep into the red. A flashing signal beneath the sign indicates that the flow control valve has been shut in response.[end if]".
	The valves is scenery in loose floor panel. valves has a truth state called flowing. flowing of valves is false.
	The description of valves is "[recall][ln 1]Several sets of emergeny valves rest next to one another. [if flowing of valves is true]All of the valves appear to be open and flowing correctly.[else]All the valves appear normal except for the one labeled 'Nano-Biotic' which is closed.[end if]"
	
	Factory cell is scenery in Life Support Subfloor. Description of factory cell is "A large cylindrical holding tank glows as billions of nanobots are self replicating. A readout above the tank indicates that nano-biotic replication is set to [if low pressure of status is false]HIGH[else]LOW[end if]. You notice a screen to the side of the cylinder, it looks as if you can SET production to either HIGH or LOW."
	
	Nano-Biotic is scenery inside loose floor panel.
	Description of nano-biotic is "[if flowing of valves is false]The pipe is currently blocked by the shut valve, preventing the nano-biotic from circulating.[else]The nano-biotic is now freely flowing through the safety valve.[end if]".
	Pipes is scenery in Life Support.
	Machines is scenery in Life support.

Chapter 3 - Rules

Section - General

	Instead of going nowhere: say "While you could walk to the [noun], you laugh at the notion. What an old form of travel!"
	
	Understand "wrist/arm" as Fast Transit Unit.
	Understand "engine" as engines.
	
	Instead of dropping fast transit unit, say "Its part of your arm! Besides you wouldnt want to have to walk everywhere would you?"
	
	Transit is an action applying to one thing.
	Understand "go to [any room]" or "go [any room]" or "to [any room]" or "goto [any room]" as Transit. 

	To Reincarnate:
		say "[ln 1]Press any key to respawn.";
		wait for any key;
		move player to Spawning Chamber;
		now the Version of player is Version of player plus 1.
		
	Carry out Transit:
	if the noun is listed in playspace:
		if the noun is Server Room and Server Room is not visited:
			Add Serv1Obj to objs of player;
		if the noun is Stasis Chambers and Stasis Chambers is not visited:
			Add Stas1Obj to objs of player;
		say "The fast transit unit begins to emit a faint humming. The noise grows more intense and the unit starts giving off light. [line break]FLASH.[line break]You are now in the [noun].";
		now the player is in the noun;
	otherwise:
		say "[The noun] is not on the list of acceptable locations."

	To say available rooms:
	repeat with curr running through playspace:
		say "[line break][curr]".
		
	To say ln (num - number):
	let n be 0;
	while n is less than num:
		say "[line break]";
		now n is n plus 1.
	
	Every turn:
	if running of server is true and flowing of valves is true:
		progress MainObj;
	else:
		regress Main2Obj;
	if BadgeMem is listed in mems of player and CommMem is listed in mems of player:
		progress Main2Obj;
	if Main3Obj is listed in objs of player:
		now revelation is true;
	else:
		now revelation is false.
			
Section - Initialization

	When play begins:
		Add MainObj to objs of player.

Section - Objectives

	Instead of thinking:
		recall.
		
	To recall:
	say "For a moment you pause and reflect on what you've done, and still need to do:";
	repeat with curr running through objs of player:
		say "[ln 2]";
		say goals of curr;
	say "[ln 1]".
		
	To progress (current - objective):
	if current is listed in objs of player:
		remove current from objs of player;
		if target of current is not NullObj:
			add target of current to objs of player.

	To regress (current - objective):
	if current is listed in objs of player:
		remove current from objs of player;
		if preobj of current is not NullObj:
			add preobj of current to objs of player.

Section - Memories

	Before examining something:
	if mem of the noun is not empty:
		repeat with curr running through mem of the noun:
			if prereq of curr is NullMem or prereq of curr is listed in mems of player:
				add mem of the noun to mems of player;
				remove curr from mem of the noun;
				say "A memory flashes through your head.";
				say collection of curr.
	
	To say recall:	
	repeat with curr running through mems of player:
		if the noun is listed in targets of curr:
			say thoughts of curr;
			say "The memory fades...[ln 2]".
				
	To recall (current - memory):
	if current is listed in mems of player:
		say "[ln 1][thoughts of current]".
	
	To gain (current - memory):
	if current is not listed in mems of player:
		Add current to mems of player;
		say "A memory flashes through your head.";
		say collection of current.

Section - Bridge

	To say command desc:
	say "[ln 2]The first vessel";
	if badgeMem is listed in mems of player:
		say " contains a familiar face. Rorge Anderson. Lead Runtime Scientist. Even now as the ship is seemingly falling to pieces, Rorge manages to slumber soundly. Though in fairness the vessel hardly gives him a choice.";
	else:
		say " contains a man you've seen before, a flicker of a memory crosses your mind but flits away before you can grasp it.";
	say "[ln 1]In the second vessel";
	if CommMem is listed in mems of player: 
		say " lies Leandra Ramm. Commander E.D.N Tabernacle.  Even in hypersleep her look is stern. Yet there is a softness to her that you cant quite explain.";
	else:
		say " is a woman of refined beauty.";
	say "[ln 1]Finally, the third vessel";
	if revelation is true:
		say ", a curious raised rectangle just above the viewing pane is covered in frost. You check the others, they have matching rectangles on their vessels as well. Wiping them clean in turn you reveal name plates. Rorge and Leandra. A smile crosses your lips. You head back to the third vessel and draw your thumb across the plate.[ln 2]A memory flashes through your head.[ln 2][italic type]Well that about wraps it up, I have done all I can. Now our fate is in the hands of the Tabernacle, though really they have been and will continue to be my hands. We could never test my solution back home, cloning has always been far to controversial. But ethics can take a back seat when the survival of our race is at stake. Besides there is no one I trust more with my life than myself.[ln 2]The command vessels are downright luxurious compared to the lodgings of the crew, but after all my hard work I deserve a quality rest.[ln 2][roman type]The memory fades....[ln 2]Your mind reels. It is your name you see labeled on the vessel. Looking inside you see the spitting image of yourself, only decades older.[ln 2]Your wrist startles you with a loud beep. You look down at your fast transit unit to see a message now being displayed.  'Ship Status: Fully Operational... Zero errors detected after alloted lifespan. Prepare of reclamation' You take one last look back at your figure resting peacefully in the vessel. Then everything goes dark.";
		end the story;
	else:
		say " holds an unremarkable figure, old and wrinkly, peacefully slumbering beneath the viewing pane."

Section - Labs

	Understand "lab" as Labs.
	Understand "downtime science" or "science" as experiments.

Section - Server Room

	To decide if Right Tower is activated:
	if level1 of Right is true and level2 of right is true and level3 of right is true, decide yes;
	else decide no.

	Instead of examining reflection, say "[Description of player][ln 1]".

	Power Switch it to is an action applying to two things.
	Understand "transfer [any Hanoi] to [any Hanoi]" or "t [any Hanoi] [any Hanoi]" as Power Switch it to.
	Understand "towers" as tower.
	Understand "large wires" as wires.
	
	To Experimental Death:
		say "You walk up to the tower, it looks vuagely familiar, as if you have seen this thing before. But the memory falls like sand between your fingers. You know you need to do something with the breaker switches that you see. You decide to flip one at random, hopefully it will jog your memory. [ln 2]As you flip the switch, a loud popping noise startles you, but not quite as much as the thousands of volts now coursing through your body. You are dead before you hit the ground.";
		Reincarnate.

	After examining terminal:
		progress Serv1Obj.

	After examining Left Tower:
	if serverMem is not listed in mems of player:
		Experimental Death;
	else:
		say "The top node is [if level1 of Left Tower is false]not [end if]powered. The middle node is [if level2 of Left Tower is false]not [end if]powered. The bottom node is [if level3 of Left Tower is false]not [end if]powered."
	
	After examining Middle Tower:
	if serverMem is not listed in mems of player:
		Experimental Death;
	else: 
		say "The top node is [if level1 of Middle Tower is false]not [end if]powered. The middle node is [if level2 of Middle Tower is false]not [end if]powered. The bottom node is [if level3 of Middle Tower is false]not [end if]powered."
	
	After examining Right Tower:
	if serverMem is not listed in mems of player:
		Experimental Death;
	else: 
		say "The top node is [if level1 of Right Tower is false]not [end if]powered. The middle node is [if level2 of Right Tower is false]not [end if]powered. The bottom node is [if level3 of Right Tower is false]not [end if]powered."

	Carry out Power Switch it to:
	if running of server is true:
		say "The servers are already running!";
	else if noun is second noun:
		say "Thats the same tower!";
	else if level1 of noun is true:
		now level1 of noun is false;
		now level1 of second noun is true;
		say "The top node of the [noun] has been deactivated and the top node of the [second noun] has been activated.";
	else if level2 of noun is true:
		if level1 of second noun is true:
			say "That would not be wise...";
		else:
			now level2 of noun is false;
			now level2 of second noun is true;
			say "The middle node of the [noun] has been deactivated and the middle node of the [second noun] has been activated.";
	else if level3 of noun is true:
		if level1 of second noun is true or level2 of second noun is true:
			say "That would not be wise...";
		else:
			now level3 of noun is false;
			now level3 of second noun is true;
			say "The bottom node of the [noun] has been deactivated and the bottom node of the [second noun] has been activated.";
	else:
		say "[noun] has no power levels activated!";
	if Right Tower is activated and running of server is false:
		now running of server is true;
		progress Serv2Obj;
		say "[ln 1]When the final node gets activated the room immediately springs to life.  Fans begin to roar as the servers run through their boot sequences."


Section - Stasis Chambers

	Understand "stasis chamber" as stasis chambers.

	Instead of opening loose floor panel:
	if loose floor panel is open:
		say "The panel is already open!";
	else:
		say "You slide the panel from its place on the floor, revealing a set of valves.";
		now loose floor panel is open.

	After examining status screen:
		progress Stas1Obj.
		
	After examining valves:
		progress Stas1Obj.

	Instead of closing loose floor panel, say "You see no need to close the panel, you may need to access the valves later."
	
	Open pressure valve is an action applying to nothing.
	Understand "open valve" or "turn valve" or "override valve" or "override nano biotic" or "override nano-biotic" or "open nano-biotic valve" or "open nano biotic valve" as open pressure valve.
	
	High pressure is an action applying to nothing.
	Understand "set high" as high pressure.
	
	Low pressure is an action applying to nothing.
	Understand "set low" as low pressure.
	
	Understand "valve" as valves.
	Understand "pod/people/passengers" as pods.
	
	Carry out high pressure:
	if location of player is Life Support Subfloor:
		if low pressure of status is false:
			say "The pressure is already high!";
		else:
			say "The glow intensifies and activity in the as a tempest of activity erupts inside the cylinder. The readout now shows HIGH.";
			now low pressure of status is false;
			if flowing of valves is true:
				say "[ln 1]An alarm goes off and you hear something mechanical slam above you. Presumably the safety valve just shut.";
				regress stas3Obj;
				now flowing of valves is false;
	else:
		say "You see no such thing.".
	
	Carry out low pressure:
	if location of player is Life Support Subfloor:
		if low pressure of status is true:
			say "The pressure is already low!";
		else:
			say "The glow becomes faint and activity in the cylinder dies down. The readout now shows LOW.";
			progress stas2Obj;
			now low pressure of status is true;
	else:
		say "You see no such thing.".
	
	Carry out open pressure valve:
	if location of player is Stasis:
		if flowing of valves is true:
			say "The valve is already open!";
		else:
			if low pressure of status is true:
				say "The valve opens with a hiss, you can feel the pipes shiver as the nano-biotic begins to rush past. You can see the nano-biotic flowing around the nearby pods and it spreads quickly.";
				progress stas4Obj;
				now flowing of valves is true;
				now fixed of Stasis is true;
			else:
				say "You twist the lever releasing the nano-biotic. The pipe begins to rattle as the nano-biotic surges through the system. The shuttering reaches a climax as a safety release valve bursts open showering you in nano-biotic. The valve slams shut, but not before you become covered in thick thick metallic paste. Reacting to the foreign material, the nano-biotic begins to digest you. It is slow and agonizing death.";
				Reincarnate;
	else:
		say "You see no such thing.".